entry64.S 30.7 KB
Newer Older
Linus Torvalds's avatar
Linus Torvalds committed
1
/*
2
 *  arch/s390/kernel/entry64.S
Linus Torvalds's avatar
Linus Torvalds committed
3 4
 *    S390 low-level entry points.
 *
5
 *    Copyright (C) IBM Corp. 1999,2006
Linus Torvalds's avatar
Linus Torvalds committed
6
 *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
Heiko Carstens's avatar
Heiko Carstens committed
7 8
 *		 Hartmut Penner (hp@de.ibm.com),
 *		 Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
9
 *		 Heiko Carstens <heiko.carstens@de.ibm.com>
Linus Torvalds's avatar
Linus Torvalds committed
10 11 12 13
 */

#include <linux/sys.h>
#include <linux/linkage.h>
14
#include <linux/init.h>
Linus Torvalds's avatar
Linus Torvalds committed
15 16 17 18 19
#include <asm/cache.h>
#include <asm/lowcore.h>
#include <asm/errno.h>
#include <asm/ptrace.h>
#include <asm/thread_info.h>
20
#include <asm/asm-offsets.h>
Linus Torvalds's avatar
Linus Torvalds committed
21 22 23 24 25 26 27
#include <asm/unistd.h>
#include <asm/page.h>

/*
 * Stack layout for the system_call stack entry.
 * The first few entries are identical to the user_regs_struct.
 */
Heiko Carstens's avatar
Heiko Carstens committed
28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50
SP_PTREGS    =	STACK_FRAME_OVERHEAD
SP_ARGS      =	STACK_FRAME_OVERHEAD + __PT_ARGS
SP_PSW	     =	STACK_FRAME_OVERHEAD + __PT_PSW
SP_R0	     =	STACK_FRAME_OVERHEAD + __PT_GPRS
SP_R1	     =	STACK_FRAME_OVERHEAD + __PT_GPRS + 8
SP_R2	     =	STACK_FRAME_OVERHEAD + __PT_GPRS + 16
SP_R3	     =	STACK_FRAME_OVERHEAD + __PT_GPRS + 24
SP_R4	     =	STACK_FRAME_OVERHEAD + __PT_GPRS + 32
SP_R5	     =	STACK_FRAME_OVERHEAD + __PT_GPRS + 40
SP_R6	     =	STACK_FRAME_OVERHEAD + __PT_GPRS + 48
SP_R7	     =	STACK_FRAME_OVERHEAD + __PT_GPRS + 56
SP_R8	     =	STACK_FRAME_OVERHEAD + __PT_GPRS + 64
SP_R9	     =	STACK_FRAME_OVERHEAD + __PT_GPRS + 72
SP_R10	     =	STACK_FRAME_OVERHEAD + __PT_GPRS + 80
SP_R11	     =	STACK_FRAME_OVERHEAD + __PT_GPRS + 88
SP_R12	     =	STACK_FRAME_OVERHEAD + __PT_GPRS + 96
SP_R13	     =	STACK_FRAME_OVERHEAD + __PT_GPRS + 104
SP_R14	     =	STACK_FRAME_OVERHEAD + __PT_GPRS + 112
SP_R15	     =	STACK_FRAME_OVERHEAD + __PT_GPRS + 120
SP_ORIG_R2   =	STACK_FRAME_OVERHEAD + __PT_ORIG_GPR2
SP_ILC	     =	STACK_FRAME_OVERHEAD + __PT_ILC
SP_TRAP      =	STACK_FRAME_OVERHEAD + __PT_TRAP
SP_SIZE      =	STACK_FRAME_OVERHEAD + __PT_SIZE
Linus Torvalds's avatar
Linus Torvalds committed
51 52 53 54

STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
STACK_SIZE  = 1 << STACK_SHIFT

Martin Schwidefsky's avatar
Martin Schwidefsky committed
55
_TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
56
		 _TIF_MCCK_PENDING | _TIF_RESTART_SVC | _TIF_SINGLE_STEP )
Martin Schwidefsky's avatar
Martin Schwidefsky committed
57
_TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
58
		 _TIF_MCCK_PENDING)
Linus Torvalds's avatar
Linus Torvalds committed
59 60 61

#define BASED(name) name-system_call(%r13)

62 63 64 65 66 67 68 69
#ifdef CONFIG_TRACE_IRQFLAGS
	.macro	TRACE_IRQS_ON
	 brasl	%r14,trace_hardirqs_on
	.endm

	.macro	TRACE_IRQS_OFF
	 brasl	%r14,trace_hardirqs_off
	.endm
70

71 72 73 74 75 76 77
	.macro TRACE_IRQS_CHECK
	tm	SP_PSW(%r15),0x03	# irqs enabled?
	jz	0f
	brasl	%r14,trace_hardirqs_on
	j	1f
0:	brasl	%r14,trace_hardirqs_off
1:
78
	.endm
79 80 81
#else
#define TRACE_IRQS_ON
#define TRACE_IRQS_OFF
82 83 84 85 86 87 88 89 90 91 92
#define TRACE_IRQS_CHECK
#endif

#ifdef CONFIG_LOCKDEP
	.macro	LOCKDEP_SYS_EXIT
	tm	SP_PSW+1(%r15),0x01	# returning to user ?
	jz	0f
	brasl	%r14,lockdep_sys_exit
0:
	.endm
#else
93
#define LOCKDEP_SYS_EXIT
94 95
#endif

Heiko Carstens's avatar
Heiko Carstens committed
96
	.macro	STORE_TIMER lc_offset
Linus Torvalds's avatar
Linus Torvalds committed
97 98 99 100 101 102
#ifdef CONFIG_VIRT_CPU_ACCOUNTING
	stpt	\lc_offset
#endif
	.endm

#ifdef CONFIG_VIRT_CPU_ACCOUNTING
Heiko Carstens's avatar
Heiko Carstens committed
103
	.macro	UPDATE_VTIME lc_from,lc_to,lc_sum
Linus Torvalds's avatar
Linus Torvalds committed
104 105 106 107 108 109 110 111 112 113 114 115 116 117 118
	lg	%r10,\lc_from
	slg	%r10,\lc_to
	alg	%r10,\lc_sum
	stg	%r10,\lc_sum
	.endm
#endif

/*
 * Register usage in interrupt handlers:
 *    R9  - pointer to current task structure
 *    R13 - pointer to literal pool
 *    R14 - return register for function calls
 *    R15 - kernel stack pointer
 */

Heiko Carstens's avatar
Heiko Carstens committed
119
	.macro	SAVE_ALL_BASE savearea
Linus Torvalds's avatar
Linus Torvalds committed
120 121 122 123
	stmg	%r12,%r15,\savearea
	larl	%r13,system_call
	.endm

124 125 126 127 128
	.macro	SAVE_ALL_SVC psworg,savearea
	la	%r12,\psworg
	lg	%r15,__LC_KERNEL_STACK	# problem state -> load ksp
	.endm

129
	.macro	SAVE_ALL_SYNC psworg,savearea
Linus Torvalds's avatar
Linus Torvalds committed
130 131 132 133
	la	%r12,\psworg
	tm	\psworg+1,0x01		# test problem state bit
	jz	2f			# skip stack setup save
	lg	%r15,__LC_KERNEL_STACK	# problem state -> load ksp
134 135 136 137 138 139 140 141 142 143 144
#ifdef CONFIG_CHECK_STACK
	j	3f
2:	tml	%r15,STACK_SIZE - CONFIG_STACK_GUARD
	jz	stack_overflow
3:
#endif
2:
	.endm

	.macro	SAVE_ALL_ASYNC psworg,savearea
	la	%r12,\psworg
Linus Torvalds's avatar
Linus Torvalds committed
145 146 147 148 149 150 151
	tm	\psworg+1,0x01		# test problem state bit
	jnz	1f			# from user -> load kernel stack
	clc	\psworg+8(8),BASED(.Lcritical_end)
	jhe	0f
	clc	\psworg+8(8),BASED(.Lcritical_start)
	jl	0f
	brasl	%r14,cleanup_critical
152
	tm	1(%r12),0x01		# retest problem state after cleanup
Linus Torvalds's avatar
Linus Torvalds committed
153 154 155 156 157 158 159 160 161 162 163 164
	jnz	1f
0:	lg	%r14,__LC_ASYNC_STACK	# are we already on the async. stack ?
	slgr	%r14,%r15
	srag	%r14,%r14,STACK_SHIFT
	jz	2f
1:	lg	%r15,__LC_ASYNC_STACK	# load async stack
#ifdef CONFIG_CHECK_STACK
	j	3f
2:	tml	%r15,STACK_SIZE - CONFIG_STACK_GUARD
	jz	stack_overflow
3:
#endif
165 166 167 168
2:
	.endm

	.macro	CREATE_STACK_FRAME psworg,savearea
Heiko Carstens's avatar
Heiko Carstens committed
169 170
	aghi	%r15,-SP_SIZE		# make room for registers & psw
	mvc	SP_PSW(16,%r15),0(%r12)	# move user PSW to stack
Linus Torvalds's avatar
Linus Torvalds committed
171 172 173 174 175 176 177 178
	la	%r12,\psworg
	stg	%r2,SP_ORIG_R2(%r15)	# store original content of gpr 2
	icm	%r12,12,__LC_SVC_ILC
	stmg	%r0,%r11,SP_R0(%r15)	# store gprs %r0-%r11 to kernel stack
	st	%r12,SP_ILC(%r15)
	mvc	SP_R12(32,%r15),\savearea # move %r12-%r15 to stack
	la	%r12,0
	stg	%r12,__SF_BACKCHAIN(%r15)
Heiko Carstens's avatar
Heiko Carstens committed
179
	.endm
Linus Torvalds's avatar
Linus Torvalds committed
180

181 182
	.macro	RESTORE_ALL psworg,sync
	mvc	\psworg(16),SP_PSW(%r15) # move user PSW to lowcore
Linus Torvalds's avatar
Linus Torvalds committed
183
	.if !\sync
184
	ni	\psworg+1,0xfd		# clear wait state bit
Linus Torvalds's avatar
Linus Torvalds committed
185 186 187
	.endif
	lmg	%r0,%r15,SP_R0(%r15)	# load gprs 0-15 of user
	STORE_TIMER __LC_EXIT_TIMER
188
	lpswe	\psworg			# back to caller
Linus Torvalds's avatar
Linus Torvalds committed
189 190 191 192 193 194 195 196 197
	.endm

/*
 * Scheduler resume function, called by switch_to
 *  gpr2 = (task_struct *) prev
 *  gpr3 = (task_struct *) next
 * Returns:
 *  gpr2 = prev
 */
Heiko Carstens's avatar
Heiko Carstens committed
198
	.globl	__switch_to
Linus Torvalds's avatar
Linus Torvalds committed
199 200 201
__switch_to:
	tm	__THREAD_per+4(%r3),0xe8 # is the new process using per ?
	jz	__switch_to_noper		# if not we're fine
Heiko Carstens's avatar
Heiko Carstens committed
202 203 204 205
	stctg	%c9,%c11,__SF_EMPTY(%r15)# We are using per stuff
	clc	__THREAD_per(24,%r3),__SF_EMPTY(%r15)
	je	__switch_to_noper	     # we got away without bashing TLB's
	lctlg	%c9,%c11,__THREAD_per(%r3)	# Nope we didn't
Linus Torvalds's avatar
Linus Torvalds committed
206
__switch_to_noper:
Heiko Carstens's avatar
Heiko Carstens committed
207
	lg	%r4,__THREAD_info(%r2)		    # get thread_info of prev
208 209 210 211 212 213
	tm	__TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
	jz	__switch_to_no_mcck
	ni	__TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
	lg	%r4,__THREAD_info(%r3)		    # get thread_info of next
	oi	__TI_flags+7(%r4),_TIF_MCCK_PENDING # set it in next
__switch_to_no_mcck:
Heiko Carstens's avatar
Heiko Carstens committed
214
	stmg	%r6,%r15,__SF_GPRS(%r15)# store __switch_to registers of prev task
Linus Torvalds's avatar
Linus Torvalds committed
215 216
	stg	%r15,__THREAD_ksp(%r2)	# store kernel stack to prev->tss.ksp
	lg	%r15,__THREAD_ksp(%r3)	# load kernel stack from next->tss.ksp
Heiko Carstens's avatar
Heiko Carstens committed
217
	lmg	%r6,%r15,__SF_GPRS(%r15)# load __switch_to registers of next task
Linus Torvalds's avatar
Linus Torvalds committed
218 219
	stg	%r3,__LC_CURRENT	# __LC_CURRENT = current task struct
	lctl	%c4,%c4,__TASK_pid(%r3) # load pid to control reg. 4
Heiko Carstens's avatar
Heiko Carstens committed
220
	lg	%r3,__THREAD_info(%r3)	# load thread_info from task struct
Linus Torvalds's avatar
Linus Torvalds committed
221 222 223 224 225 226 227 228 229 230 231
	stg	%r3,__LC_THREAD_INFO
	aghi	%r3,STACK_SIZE
	stg	%r3,__LC_KERNEL_STACK	# __LC_KERNEL_STACK = new kernel stack
	br	%r14

__critical_start:
/*
 * SVC interrupt handler routine. System calls are synchronous events and
 * are executed with interrupts enabled.
 */

Heiko Carstens's avatar
Heiko Carstens committed
232
	.globl	system_call
Linus Torvalds's avatar
Linus Torvalds committed
233 234 235 236
system_call:
	STORE_TIMER __LC_SYNC_ENTER_TIMER
sysc_saveall:
	SAVE_ALL_BASE __LC_SAVE_AREA
237
	SAVE_ALL_SVC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
Heiko Carstens's avatar
Heiko Carstens committed
238 239
	CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
	llgh	%r7,__LC_SVC_INT_CODE	# get svc number from lowcore
Linus Torvalds's avatar
Linus Torvalds committed
240 241 242 243 244 245 246 247 248 249
#ifdef CONFIG_VIRT_CPU_ACCOUNTING
sysc_vtime:
	UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
sysc_stime:
	UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
sysc_update:
	mvc	__LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
#endif
sysc_do_svc:
	lg	%r9,__LC_THREAD_INFO	# load pointer to thread_info struct
Heiko Carstens's avatar
Heiko Carstens committed
250
	slag	%r7,%r7,2	# *4 and test for svc 0
Linus Torvalds's avatar
Linus Torvalds committed
251 252 253 254
	jnz	sysc_nr_ok
	# svc 0: system call number in %r1
	cl	%r1,BASED(.Lnr_syscalls)
	jnl	sysc_nr_ok
Heiko Carstens's avatar
Heiko Carstens committed
255 256
	lgfr	%r7,%r1 	# clear high word in r1
	slag	%r7,%r7,2	# svc 0: system call number in %r1
Linus Torvalds's avatar
Linus Torvalds committed
257 258 259
sysc_nr_ok:
	mvc	SP_ARGS(8,%r15),SP_R7(%r15)
sysc_do_restart:
Heiko Carstens's avatar
Heiko Carstens committed
260
	larl	%r10,sys_call_table
261
#ifdef CONFIG_COMPAT
262 263
	tm	__TI_flags+5(%r9),(_TIF_31BIT>>16)  # running in 31 bit mode ?
	jno	sysc_noemu
Heiko Carstens's avatar
Heiko Carstens committed
264
	larl	%r10,sys_call_table_emu  # use 31 bit emulation system calls
Linus Torvalds's avatar
Linus Torvalds committed
265 266 267
sysc_noemu:
#endif
	tm	__TI_flags+7(%r9),(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT)
Heiko Carstens's avatar
Heiko Carstens committed
268 269 270 271
	lgf	%r8,0(%r7,%r10) # load address of system call routine
	jnz	sysc_tracesys
	basr	%r14,%r8	# call sys_xxxx
	stg	%r2,SP_R2(%r15) # store return value (change R2 on stack)
Linus Torvalds's avatar
Linus Torvalds committed
272 273 274

sysc_return:
	tm	__TI_flags+7(%r9),_TIF_WORK_SVC
Heiko Carstens's avatar
Heiko Carstens committed
275
	jnz	sysc_work	# there is work to do (signals etc.)
276 277 278 279 280 281
sysc_restore:
#ifdef CONFIG_TRACE_IRQFLAGS
	larl	%r1,sysc_restore_trace_psw
	lpswe	0(%r1)
sysc_restore_trace:
	TRACE_IRQS_CHECK
282
	LOCKDEP_SYS_EXIT
283
#endif
Linus Torvalds's avatar
Linus Torvalds committed
284
sysc_leave:
Heiko Carstens's avatar
Heiko Carstens committed
285
	RESTORE_ALL __LC_RETURN_PSW,1
286 287 288 289 290 291 292 293
sysc_done:

#ifdef CONFIG_TRACE_IRQFLAGS
	.align	8
	.globl sysc_restore_trace_psw
sysc_restore_trace_psw:
	.quad	0, sysc_restore_trace
#endif
Linus Torvalds's avatar
Linus Torvalds committed
294 295 296 297 298 299

#
# recheck if there is more work to do
#
sysc_work_loop:
	tm	__TI_flags+7(%r9),_TIF_WORK_SVC
300
	jz	sysc_restore	  # there is no work to do
Linus Torvalds's avatar
Linus Torvalds committed
301 302 303 304
#
# One of the work bits is on. Find out which one.
#
sysc_work:
305 306
	tm	SP_PSW+1(%r15),0x01	# returning to user ?
	jno	sysc_restore
307 308
	tm	__TI_flags+7(%r9),_TIF_MCCK_PENDING
	jo	sysc_mcck_pending
Linus Torvalds's avatar
Linus Torvalds committed
309 310
	tm	__TI_flags+7(%r9),_TIF_NEED_RESCHED
	jo	sysc_reschedule
311
	tm	__TI_flags+7(%r9),_TIF_SIGPENDING
312
	jnz	sysc_sigpending
Martin Schwidefsky's avatar
Martin Schwidefsky committed
313 314
	tm	__TI_flags+7(%r9),_TIF_NOTIFY_RESUME
	jnz	sysc_notify_resume
Linus Torvalds's avatar
Linus Torvalds committed
315 316 317 318
	tm	__TI_flags+7(%r9),_TIF_RESTART_SVC
	jo	sysc_restart
	tm	__TI_flags+7(%r9),_TIF_SINGLE_STEP
	jo	sysc_singlestep
319 320
	j	sysc_restore
sysc_work_done:
Linus Torvalds's avatar
Linus Torvalds committed
321 322 323

#
# _TIF_NEED_RESCHED is set, call schedule
Heiko Carstens's avatar
Heiko Carstens committed
324 325 326 327
#
sysc_reschedule:
	larl	%r14,sysc_work_loop
	jg	schedule	# return point is sysc_return
Linus Torvalds's avatar
Linus Torvalds committed
328

329 330 331 332 333
#
# _TIF_MCCK_PENDING is set, call handler
#
sysc_mcck_pending:
	larl	%r14,sysc_work_loop
Heiko Carstens's avatar
Heiko Carstens committed
334
	jg	s390_handle_mcck	# TIF bit will be cleared by handler
335

Linus Torvalds's avatar
Linus Torvalds committed
336
#
337
# _TIF_SIGPENDING is set, call do_signal
Linus Torvalds's avatar
Linus Torvalds committed
338
#
Heiko Carstens's avatar
Heiko Carstens committed
339
sysc_sigpending:
Linus Torvalds's avatar
Linus Torvalds committed
340
	ni	__TI_flags+7(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
Heiko Carstens's avatar
Heiko Carstens committed
341 342
	la	%r2,SP_PTREGS(%r15)	# load pt_regs
	brasl	%r14,do_signal		# call do_signal
Linus Torvalds's avatar
Linus Torvalds committed
343 344 345 346
	tm	__TI_flags+7(%r9),_TIF_RESTART_SVC
	jo	sysc_restart
	tm	__TI_flags+7(%r9),_TIF_SINGLE_STEP
	jo	sysc_singlestep
Heiko Carstens's avatar
Heiko Carstens committed
347
	j	sysc_work_loop
Linus Torvalds's avatar
Linus Torvalds committed
348

Martin Schwidefsky's avatar
Martin Schwidefsky committed
349 350 351 352 353 354 355 356
#
# _TIF_NOTIFY_RESUME is set, call do_notify_resume
#
sysc_notify_resume:
	la	%r2,SP_PTREGS(%r15)	# load pt_regs
	larl	%r14,sysc_work_loop
	jg	do_notify_resume	# call do_notify_resume

Linus Torvalds's avatar
Linus Torvalds committed
357 358 359 360 361
#
# _TIF_RESTART_SVC is set, set up registers and restart svc
#
sysc_restart:
	ni	__TI_flags+7(%r9),255-_TIF_RESTART_SVC # clear TIF_RESTART_SVC
Heiko Carstens's avatar
Heiko Carstens committed
362 363
	lg	%r7,SP_R2(%r15)		# load new svc number
	slag	%r7,%r7,2		# *4
Linus Torvalds's avatar
Linus Torvalds committed
364
	mvc	SP_R2(8,%r15),SP_ORIG_R2(%r15) # restore first argument
Heiko Carstens's avatar
Heiko Carstens committed
365 366
	lmg	%r2,%r6,SP_R2(%r15)	# load svc arguments
	j	sysc_do_restart 	# restart svc
Linus Torvalds's avatar
Linus Torvalds committed
367 368 369 370 371 372 373 374 375 376 377 378 379

#
# _TIF_SINGLE_STEP is set, call do_single_step
#
sysc_singlestep:
	ni	__TI_flags+7(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
	lhi	%r0,__LC_PGM_OLD_PSW
	sth	%r0,SP_TRAP(%r15)	# set trap indication to pgm check
	la	%r2,SP_PTREGS(%r15)	# address of register-save area
	larl	%r14,sysc_return	# load adr. of system return
	jg	do_single_step		# branch to do_sigtrap

#
Martin Schwidefsky's avatar
Martin Schwidefsky committed
380 381
# call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
# and after the system call
Linus Torvalds's avatar
Linus Torvalds committed
382 383
#
sysc_tracesys:
Heiko Carstens's avatar
Heiko Carstens committed
384
	la	%r2,SP_PTREGS(%r15)	# load pt_regs
Linus Torvalds's avatar
Linus Torvalds committed
385 386
	la	%r3,0
	srl	%r7,2
Heiko Carstens's avatar
Heiko Carstens committed
387
	stg	%r7,SP_R2(%r15)
Martin Schwidefsky's avatar
Martin Schwidefsky committed
388
	brasl	%r14,do_syscall_trace_enter
Linus Torvalds's avatar
Linus Torvalds committed
389
	lghi	%r0,NR_syscalls
Martin Schwidefsky's avatar
Martin Schwidefsky committed
390
	clgr	%r0,%r2
Linus Torvalds's avatar
Linus Torvalds committed
391
	jnh	sysc_tracenogo
Martin Schwidefsky's avatar
Martin Schwidefsky committed
392
	slag	%r7,%r2,2		# *4
Linus Torvalds's avatar
Linus Torvalds committed
393 394
	lgf	%r8,0(%r7,%r10)
sysc_tracego:
Heiko Carstens's avatar
Heiko Carstens committed
395 396 397 398
	lmg	%r3,%r6,SP_R3(%r15)
	lg	%r2,SP_ORIG_R2(%r15)
	basr	%r14,%r8		# call sys_xxx
	stg	%r2,SP_R2(%r15)		# store return value
Linus Torvalds's avatar
Linus Torvalds committed
399 400
sysc_tracenogo:
	tm	__TI_flags+7(%r9),(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT)
Heiko Carstens's avatar
Heiko Carstens committed
401 402 403
	jz	sysc_return
	la	%r2,SP_PTREGS(%r15)	# load pt_regs
	larl	%r14,sysc_return	# return point is sysc_return
Martin Schwidefsky's avatar
Martin Schwidefsky committed
404
	jg	do_syscall_trace_exit
Linus Torvalds's avatar
Linus Torvalds committed
405 406 407 408

#
# a new process exits the kernel with ret_from_fork
#
Heiko Carstens's avatar
Heiko Carstens committed
409
	.globl	ret_from_fork
Linus Torvalds's avatar
Linus Torvalds committed
410 411 412 413 414 415
ret_from_fork:
	lg	%r13,__LC_SVC_NEW_PSW+8
	lg	%r9,__LC_THREAD_INFO	# load pointer to thread_info struct
	tm	SP_PSW+1(%r15),0x01	# forking a kernel thread ?
	jo	0f
	stg	%r15,SP_R15(%r15)	# store stack pointer for new kthread
Heiko Carstens's avatar
Heiko Carstens committed
416
0:	brasl	%r14,schedule_tail
417
	TRACE_IRQS_ON
Heiko Carstens's avatar
Heiko Carstens committed
418
	stosm	24(%r15),0x03		# reenable interrupts
Linus Torvalds's avatar
Linus Torvalds committed
419 420 421
	j	sysc_return

#
422 423
# kernel_execve function needs to deal with pt_regs that is not
# at the usual place
Linus Torvalds's avatar
Linus Torvalds committed
424
#
425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450
	.globl	kernel_execve
kernel_execve:
	stmg	%r12,%r15,96(%r15)
	lgr	%r14,%r15
	aghi	%r15,-SP_SIZE
	stg	%r14,__SF_BACKCHAIN(%r15)
	la	%r12,SP_PTREGS(%r15)
	xc	0(__PT_SIZE,%r12),0(%r12)
	lgr	%r5,%r12
	brasl	%r14,do_execve
	ltgfr	%r2,%r2
	je	0f
	aghi	%r15,SP_SIZE
	lmg	%r12,%r15,96(%r15)
	br	%r14
	# execve succeeded.
0:	stnsm	__SF_EMPTY(%r15),0xfc	# disable interrupts
	lg	%r15,__LC_KERNEL_STACK	# load ksp
	aghi	%r15,-SP_SIZE		# make room for registers & psw
	lg	%r13,__LC_SVC_NEW_PSW+8
	lg	%r9,__LC_THREAD_INFO
	mvc	SP_PTREGS(__PT_SIZE,%r15),0(%r12)	# copy pt_regs
	xc	__SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
	stosm	__SF_EMPTY(%r15),0x03	# reenable interrupts
	brasl	%r14,execve_tail
	j	sysc_return
Linus Torvalds's avatar
Linus Torvalds committed
451 452 453 454 455

/*
 * Program check handler routine
 */

Heiko Carstens's avatar
Heiko Carstens committed
456
	.globl	pgm_check_handler
Linus Torvalds's avatar
Linus Torvalds committed
457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472
pgm_check_handler:
/*
 * First we need to check for a special case:
 * Single stepping an instruction that disables the PER event mask will
 * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
 * For a single stepped SVC the program check handler gets control after
 * the SVC new PSW has been loaded. But we want to execute the SVC first and
 * then handle the PER event. Therefore we update the SVC old PSW to point
 * to the pgm_check_handler and branch to the SVC handler after we checked
 * if we have to load the kernel stack register.
 * For every other possible cause for PER event without the PER mask set
 * we just ignore the PER event (FIXME: is there anything we have to do
 * for LPSW?).
 */
	STORE_TIMER __LC_SYNC_ENTER_TIMER
	SAVE_ALL_BASE __LC_SAVE_AREA
Heiko Carstens's avatar
Heiko Carstens committed
473 474
	tm	__LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
	jnz	pgm_per 		 # got per exception -> special case
475
	SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
476
	CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
Linus Torvalds's avatar
Linus Torvalds committed
477 478 479 480 481 482 483 484 485
#ifdef CONFIG_VIRT_CPU_ACCOUNTING
	tm	SP_PSW+1(%r15),0x01	# interrupting from user ?
	jz	pgm_no_vtime
	UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
	UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
	mvc	__LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
pgm_no_vtime:
#endif
	lg	%r9,__LC_THREAD_INFO	# load pointer to thread_info struct
486
	mvc	SP_ARGS(8,%r15),__LC_LAST_BREAK
487
	TRACE_IRQS_OFF
Heiko Carstens's avatar
Heiko Carstens committed
488
	lgf	%r3,__LC_PGM_ILC	# load program interruption code
Linus Torvalds's avatar
Linus Torvalds committed
489 490 491
	lghi	%r8,0x7f
	ngr	%r8,%r3
pgm_do_call:
Heiko Carstens's avatar
Heiko Carstens committed
492 493 494 495
	sll	%r8,3
	larl	%r1,pgm_check_table
	lg	%r1,0(%r8,%r1)		# load address of handler routine
	la	%r2,SP_PTREGS(%r15)	# address of register-save area
Linus Torvalds's avatar
Linus Torvalds committed
496
	larl	%r14,sysc_return
Heiko Carstens's avatar
Heiko Carstens committed
497
	br	%r1			# branch to interrupt-handler
Linus Torvalds's avatar
Linus Torvalds committed
498 499 500 501 502

#
# handle per exception
#
pgm_per:
Heiko Carstens's avatar
Heiko Carstens committed
503 504
	tm	__LC_PGM_OLD_PSW,0x40	# test if per event recording is on
	jnz	pgm_per_std		# ok, normal per event from user space
Linus Torvalds's avatar
Linus Torvalds committed
505
# ok its one of the special cases, now we need to find out which one
Heiko Carstens's avatar
Heiko Carstens committed
506 507
	clc	__LC_PGM_OLD_PSW(16),__LC_SVC_NEW_PSW
	je	pgm_svcper
Linus Torvalds's avatar
Linus Torvalds committed
508 509
# no interesting special case, ignore PER event
	lmg	%r12,%r15,__LC_SAVE_AREA
Heiko Carstens's avatar
Heiko Carstens committed
510
	lpswe	__LC_PGM_OLD_PSW
Linus Torvalds's avatar
Linus Torvalds committed
511 512 513 514 515

#
# Normal per exception
#
pgm_per_std:
516
	SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
517
	CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
Linus Torvalds's avatar
Linus Torvalds committed
518 519 520 521 522 523 524 525 526
#ifdef CONFIG_VIRT_CPU_ACCOUNTING
	tm	SP_PSW+1(%r15),0x01	# interrupting from user ?
	jz	pgm_no_vtime2
	UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
	UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
	mvc	__LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
pgm_no_vtime2:
#endif
	lg	%r9,__LC_THREAD_INFO	# load pointer to thread_info struct
527
	TRACE_IRQS_OFF
Linus Torvalds's avatar
Linus Torvalds committed
528
	lg	%r1,__TI_task(%r9)
Michael Grundy's avatar
Michael Grundy committed
529 530
	tm	SP_PSW+1(%r15),0x01	# kernel per event ?
	jz	kernel_per
Linus Torvalds's avatar
Linus Torvalds committed
531 532 533 534
	mvc	__THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
	mvc	__THREAD_per+__PER_address(8,%r1),__LC_PER_ADDRESS
	mvc	__THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
	oi	__TI_flags+7(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
Heiko Carstens's avatar
Heiko Carstens committed
535
	lgf	%r3,__LC_PGM_ILC	# load program interruption code
Linus Torvalds's avatar
Linus Torvalds committed
536
	lghi	%r8,0x7f
Heiko Carstens's avatar
Heiko Carstens committed
537
	ngr	%r8,%r3			# clear per-event-bit and ilc
Linus Torvalds's avatar
Linus Torvalds committed
538 539 540 541 542 543 544
	je	sysc_return
	j	pgm_do_call

#
# it was a single stepped SVC that is causing all the trouble
#
pgm_svcper:
545
	SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
546
	CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
Linus Torvalds's avatar
Linus Torvalds committed
547 548 549 550 551
#ifdef CONFIG_VIRT_CPU_ACCOUNTING
	UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
	UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
	mvc	__LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
#endif
Heiko Carstens's avatar
Heiko Carstens committed
552
	llgh	%r7,__LC_SVC_INT_CODE	# get svc number from lowcore
Linus Torvalds's avatar
Linus Torvalds committed
553 554 555 556 557 558
	lg	%r9,__LC_THREAD_INFO	# load pointer to thread_info struct
	lg	%r1,__TI_task(%r9)
	mvc	__THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
	mvc	__THREAD_per+__PER_address(8,%r1),__LC_PER_ADDRESS
	mvc	__THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
	oi	__TI_flags+7(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
559
	TRACE_IRQS_ON
Linus Torvalds's avatar
Linus Torvalds committed
560 561 562
	stosm	__SF_EMPTY(%r15),0x03	# reenable interrupts
	j	sysc_do_svc

Michael Grundy's avatar
Michael Grundy committed
563 564 565 566 567 568 569
#
# per was called from kernel, must be kprobes
#
kernel_per:
	lhi	%r0,__LC_PGM_OLD_PSW
	sth	%r0,SP_TRAP(%r15)	# set trap indication to pgm check
	la	%r2,SP_PTREGS(%r15)	# address of register-save area
570
	larl	%r14,sysc_restore	# load adr. of system ret, no work
Michael Grundy's avatar
Michael Grundy committed
571 572
	jg	do_single_step		# branch to do_single_step

Linus Torvalds's avatar
Linus Torvalds committed
573 574 575
/*
 * IO interrupt handler routine
 */
Heiko Carstens's avatar
Heiko Carstens committed
576
	.globl io_int_handler
Linus Torvalds's avatar
Linus Torvalds committed
577 578 579 580
io_int_handler:
	STORE_TIMER __LC_ASYNC_ENTER_TIMER
	stck	__LC_INT_CLOCK
	SAVE_ALL_BASE __LC_SAVE_AREA+32
581
	SAVE_ALL_ASYNC __LC_IO_OLD_PSW,__LC_SAVE_AREA+32
582
	CREATE_STACK_FRAME __LC_IO_OLD_PSW,__LC_SAVE_AREA+32
Linus Torvalds's avatar
Linus Torvalds committed
583 584 585 586 587 588 589 590 591
#ifdef CONFIG_VIRT_CPU_ACCOUNTING
	tm	SP_PSW+1(%r15),0x01	# interrupting from user ?
	jz	io_no_vtime
	UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
	UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
	mvc	__LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
io_no_vtime:
#endif
	lg	%r9,__LC_THREAD_INFO	# load pointer to thread_info struct
592
	TRACE_IRQS_OFF
Heiko Carstens's avatar
Heiko Carstens committed
593 594
	la	%r2,SP_PTREGS(%r15)	# address of register-save area
	brasl	%r14,do_IRQ		# call standard irq handler
Linus Torvalds's avatar
Linus Torvalds committed
595 596
io_return:
	tm	__TI_flags+7(%r9),_TIF_WORK_INT
Heiko Carstens's avatar
Heiko Carstens committed
597
	jnz	io_work 		# there is work to do (signals etc.)
598 599 600 601 602 603
io_restore:
#ifdef CONFIG_TRACE_IRQFLAGS
	larl	%r1,io_restore_trace_psw
	lpswe	0(%r1)
io_restore_trace:
	TRACE_IRQS_CHECK
604
	LOCKDEP_SYS_EXIT
605
#endif
Linus Torvalds's avatar
Linus Torvalds committed
606
io_leave:
Heiko Carstens's avatar
Heiko Carstens committed
607
	RESTORE_ALL __LC_RETURN_PSW,0
608
io_done:
Linus Torvalds's avatar
Linus Torvalds committed
609

610 611 612 613 614 615 616
#ifdef CONFIG_TRACE_IRQFLAGS
	.align	8
	.globl io_restore_trace_psw
io_restore_trace_psw:
	.quad	0, io_restore_trace
#endif

617
#
618 619
# There is work todo, we need to check if we return to userspace, then
# check, if we are in SIE, if yes leave it
620 621 622 623
#
io_work:
	tm	SP_PSW+1(%r15),0x01	# returning to user ?
#ifndef CONFIG_PREEMPT
624 625 626 627 628 629 630 631 632 633 634
#if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
	jnz	io_work_user		# yes -> no need to check for SIE
	la	%r1, BASED(sie_opcode)	# we return to kernel here
	lg	%r2, SP_PSW+8(%r15)
	clc	0(2,%r1), 0(%r2)	# is current instruction = SIE?
	jne	io_restore		# no-> return to kernel
	lg	%r1, SP_PSW+8(%r15)	# yes-> add 4 bytes to leave SIE
	aghi	%r1, 4
	stg	%r1, SP_PSW+8(%r15)
	j	io_restore		# return to kernel
#else
635
	jno	io_restore		# no-> skip resched & signal
636
#endif
637 638
#else
	jnz	io_work_user		# yes -> do resched & signal
639 640 641 642 643 644 645 646 647 648
#if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
	la	%r1, BASED(sie_opcode)
	lg	%r2, SP_PSW+8(%r15)
	clc	0(2,%r1), 0(%r2)	# is current instruction = SIE?
	jne	0f			# no -> leave PSW alone
	lg	%r1, SP_PSW+8(%r15)	# yes-> add 4 bytes to leave SIE
	aghi	%r1, 4
	stg	%r1, SP_PSW+8(%r15)
0:
#endif
649
	# check for preemptive scheduling
Heiko Carstens's avatar
Heiko Carstens committed
650
	icm	%r0,15,__TI_precount(%r9)
651
	jnz	io_restore		# preemption is disabled
Linus Torvalds's avatar
Linus Torvalds committed
652 653 654 655
	# switch to kernel stack
	lg	%r1,SP_R15(%r15)
	aghi	%r1,-SP_SIZE
	mvc	SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
Heiko Carstens's avatar
Heiko Carstens committed
656
	xc	__SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
Linus Torvalds's avatar
Linus Torvalds committed
657 658 659
	lgr	%r15,%r1
io_resume_loop:
	tm	__TI_flags+7(%r9),_TIF_NEED_RESCHED
660
	jno	io_restore
Heiko Carstens's avatar
Heiko Carstens committed
661 662
	larl	%r14,io_resume_loop
	jg	preempt_schedule_irq
Linus Torvalds's avatar
Linus Torvalds committed
663 664
#endif

665
io_work_user:
Linus Torvalds's avatar
Linus Torvalds committed
666 667 668
	lg	%r1,__LC_KERNEL_STACK
	aghi	%r1,-SP_SIZE
	mvc	SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
Heiko Carstens's avatar
Heiko Carstens committed
669
	xc	__SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
Linus Torvalds's avatar
Linus Torvalds committed
670 671 672
	lgr	%r15,%r1
#
# One of the work bits is on. Find out which one.
673 674
# Checked are: _TIF_SIGPENDING, _TIF_RESTORE_SIGPENDING, _TIF_NEED_RESCHED
#	       and _TIF_MCCK_PENDING
Linus Torvalds's avatar
Linus Torvalds committed
675 676
#
io_work_loop:
677 678
	tm	__TI_flags+7(%r9),_TIF_MCCK_PENDING
	jo	io_mcck_pending
Linus Torvalds's avatar
Linus Torvalds committed
679 680
	tm	__TI_flags+7(%r9),_TIF_NEED_RESCHED
	jo	io_reschedule
681
	tm	__TI_flags+7(%r9),_TIF_SIGPENDING
682
	jnz	io_sigpending
Martin Schwidefsky's avatar
Martin Schwidefsky committed
683 684
	tm	__TI_flags+7(%r9),_TIF_NOTIFY_RESUME
	jnz	io_notify_resume
685 686
	j	io_restore
io_work_done:
Linus Torvalds's avatar
Linus Torvalds committed
687

688 689 690 691 692
#if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
sie_opcode:
	.long 0xb2140000
#endif

693 694 695 696
#
# _TIF_MCCK_PENDING is set, call handler
#
io_mcck_pending:
Heiko Carstens's avatar
Heiko Carstens committed
697 698
	brasl	%r14,s390_handle_mcck	# TIF bit will be cleared by handler
	j	io_work_loop
699

Linus Torvalds's avatar
Linus Torvalds committed
700 701
#
# _TIF_NEED_RESCHED is set, call schedule
Heiko Carstens's avatar
Heiko Carstens committed
702 703
#
io_reschedule:
704
	TRACE_IRQS_ON
Heiko Carstens's avatar
Heiko Carstens committed
705 706 707
	stosm	__SF_EMPTY(%r15),0x03	# reenable interrupts
	brasl	%r14,schedule		# call scheduler
	stnsm	__SF_EMPTY(%r15),0xfc	# disable I/O and ext. interrupts
708
	TRACE_IRQS_OFF
Linus Torvalds's avatar
Linus Torvalds committed
709
	tm	__TI_flags+7(%r9),_TIF_WORK_INT
710
	jz	io_restore		# there is no work to do
Linus Torvalds's avatar
Linus Torvalds committed
711 712 713
	j	io_work_loop

#
714
# _TIF_SIGPENDING or is set, call do_signal
Linus Torvalds's avatar
Linus Torvalds committed
715
#
Heiko Carstens's avatar
Heiko Carstens committed
716
io_sigpending:
717
	TRACE_IRQS_ON
Heiko Carstens's avatar
Heiko Carstens committed
718 719
	stosm	__SF_EMPTY(%r15),0x03	# reenable interrupts
	la	%r2,SP_PTREGS(%r15)	# load pt_regs
Linus Torvalds's avatar
Linus Torvalds committed
720
	brasl	%r14,do_signal		# call do_signal
Heiko Carstens's avatar
Heiko Carstens committed
721
	stnsm	__SF_EMPTY(%r15),0xfc	# disable I/O and ext. interrupts
722
	TRACE_IRQS_OFF
Heiko Carstens's avatar
Heiko Carstens committed
723
	j	io_work_loop
Linus Torvalds's avatar
Linus Torvalds committed
724

Martin Schwidefsky's avatar
Martin Schwidefsky committed
725 726 727 728 729 730 731 732 733 734 735 736
#
# _TIF_NOTIFY_RESUME or is set, call do_notify_resume
#
io_notify_resume:
	TRACE_IRQS_ON
	stosm	__SF_EMPTY(%r15),0x03	# reenable interrupts
	la	%r2,SP_PTREGS(%r15)	# load pt_regs
	brasl	%r14,do_notify_resume	# call do_notify_resume
	stnsm	__SF_EMPTY(%r15),0xfc	# disable I/O and ext. interrupts
	TRACE_IRQS_OFF
	j	io_work_loop

Linus Torvalds's avatar
Linus Torvalds committed
737 738 739
/*
 * External interrupt handler routine
 */
Heiko Carstens's avatar
Heiko Carstens committed
740
	.globl	ext_int_handler
Linus Torvalds's avatar
Linus Torvalds committed
741 742 743 744
ext_int_handler:
	STORE_TIMER __LC_ASYNC_ENTER_TIMER
	stck	__LC_INT_CLOCK
	SAVE_ALL_BASE __LC_SAVE_AREA+32
745
	SAVE_ALL_ASYNC __LC_EXT_OLD_PSW,__LC_SAVE_AREA+32
746
	CREATE_STACK_FRAME __LC_EXT_OLD_PSW,__LC_SAVE_AREA+32
Linus Torvalds's avatar
Linus Torvalds committed
747 748 749 750 751 752 753 754 755
#ifdef CONFIG_VIRT_CPU_ACCOUNTING
	tm	SP_PSW+1(%r15),0x01	# interrupting from user ?
	jz	ext_no_vtime
	UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
	UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
	mvc	__LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
ext_no_vtime:
#endif
	lg	%r9,__LC_THREAD_INFO	# load pointer to thread_info struct
756
	TRACE_IRQS_OFF
Heiko Carstens's avatar
Heiko Carstens committed
757 758 759
	la	%r2,SP_PTREGS(%r15)	# address of register-save area
	llgh	%r3,__LC_EXT_INT_CODE	# get interruption code
	brasl	%r14,do_extint
Linus Torvalds's avatar
Linus Torvalds committed
760 761
	j	io_return

762 763
__critical_end:

Linus Torvalds's avatar
Linus Torvalds committed
764 765 766
/*
 * Machine check handler routines
 */
Heiko Carstens's avatar
Heiko Carstens committed
767
	.globl mcck_int_handler
Linus Torvalds's avatar
Linus Torvalds committed
768
mcck_int_handler:
769 770
	la	%r1,4095		# revalidate r1
	spt	__LC_CPU_TIMER_SAVE_AREA-4095(%r1)	# revalidate cpu timer
Heiko Carstens's avatar
Heiko Carstens committed
771
	lmg	%r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
Linus Torvalds's avatar
Linus Torvalds committed
772
	SAVE_ALL_BASE __LC_SAVE_AREA+64
773
	la	%r12,__LC_MCK_OLD_PSW
Heiko Carstens's avatar
Heiko Carstens committed
774
	tm	__LC_MCCK_CODE,0x80	# system damage?
775
	jo	mcck_int_main		# yes -> rest of mcck code invalid
Linus Torvalds's avatar
Linus Torvalds committed
776
#ifdef CONFIG_VIRT_CPU_ACCOUNTING
777 778 779 780 781 782 783 784 785 786 787 788 789 790 791 792 793 794
	la	%r14,4095
	mvc	__LC_SAVE_AREA+104(8),__LC_ASYNC_ENTER_TIMER
	mvc	__LC_ASYNC_ENTER_TIMER(8),__LC_CPU_TIMER_SAVE_AREA-4095(%r14)
	tm	__LC_MCCK_CODE+5,0x02	# stored cpu timer value valid?
	jo	1f
	la	%r14,__LC_SYNC_ENTER_TIMER
	clc	0(8,%r14),__LC_ASYNC_ENTER_TIMER
	jl	0f
	la	%r14,__LC_ASYNC_ENTER_TIMER
0:	clc	0(8,%r14),__LC_EXIT_TIMER
	jl	0f
	la	%r14,__LC_EXIT_TIMER
0:	clc	0(8,%r14),__LC_LAST_UPDATE_TIMER
	jl	0f
	la	%r14,__LC_LAST_UPDATE_TIMER
0:	spt	0(%r14)
	mvc	__LC_ASYNC_ENTER_TIMER(8),0(%r14)
1:
Linus Torvalds's avatar
Linus Torvalds committed
795
#endif
796
	tm	__LC_MCCK_CODE+2,0x09	# mwp + ia of old psw valid?
797
	jno	mcck_int_main		# no -> skip cleanup critical
Heiko Carstens's avatar
Heiko Carstens committed
798
	tm	__LC_MCK_OLD_PSW+1,0x01 # test problem state bit
799 800 801
	jnz	mcck_int_main		# from user -> load kernel stack
	clc	__LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_end)
	jhe	mcck_int_main
Heiko Carstens's avatar
Heiko Carstens committed
802
	clc	__LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_start)
803
	jl	mcck_int_main
Heiko Carstens's avatar
Heiko Carstens committed
804
	brasl	%r14,cleanup_critical
805
mcck_int_main:
Heiko Carstens's avatar
Heiko Carstens committed
806
	lg	%r14,__LC_PANIC_STACK	# are we already on the panic stack?
807 808 809
	slgr	%r14,%r15
	srag	%r14,%r14,PAGE_SHIFT
	jz	0f
Heiko Carstens's avatar
Heiko Carstens committed
810
	lg	%r15,__LC_PANIC_STACK	# load panic stack
811
0:	CREATE_STACK_FRAME __LC_MCK_OLD_PSW,__LC_SAVE_AREA+64
812 813 814
#ifdef CONFIG_VIRT_CPU_ACCOUNTING
	tm	__LC_MCCK_CODE+2,0x08	# mwp of old psw valid?
	jno	mcck_no_vtime		# no -> no timer update
815
	tm	SP_PSW+1(%r15),0x01	# interrupting from user ?
816 817 818 819 820 821
	jz	mcck_no_vtime
	UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
	UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
	mvc	__LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
mcck_no_vtime:
#endif
822 823 824
	lg	%r9,__LC_THREAD_INFO	# load pointer to thread_info struct
	la	%r2,SP_PTREGS(%r15)	# load pt_regs
	brasl	%r14,s390_do_machine_check
Heiko Carstens's avatar
Heiko Carstens committed
825
	tm	SP_PSW+1(%r15),0x01	# returning to user ?
826 827 828 829 830 831 832 833 834
	jno	mcck_return
	lg	%r1,__LC_KERNEL_STACK	# switch to kernel stack
	aghi	%r1,-SP_SIZE
	mvc	SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
	xc	__SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
	lgr	%r15,%r1
	stosm	__SF_EMPTY(%r15),0x04	# turn dat on
	tm	__TI_flags+7(%r9),_TIF_MCCK_PENDING
	jno	mcck_return
835
	TRACE_IRQS_OFF
836
	brasl	%r14,s390_handle_mcck
837
	TRACE_IRQS_ON
Linus Torvalds's avatar
Linus Torvalds committed
838
mcck_return:
839 840 841 842 843 844 845 846 847 848 849
	mvc	__LC_RETURN_MCCK_PSW(16),SP_PSW(%r15) # move return PSW
	ni	__LC_RETURN_MCCK_PSW+1,0xfd # clear wait state bit
	lmg	%r0,%r15,SP_R0(%r15)	# load gprs 0-15
#ifdef CONFIG_VIRT_CPU_ACCOUNTING
	mvc	__LC_ASYNC_ENTER_TIMER(8),__LC_SAVE_AREA+104
	tm	__LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
	jno	0f
	stpt	__LC_EXIT_TIMER
0:
#endif
	lpswe	__LC_RETURN_MCCK_PSW	# back to caller
Linus Torvalds's avatar
Linus Torvalds committed
850 851 852 853

/*
 * Restart interruption handler, kick starter for additional CPUs
 */
854
#ifdef CONFIG_SMP
855
	__CPUINIT
Heiko Carstens's avatar
Heiko Carstens committed
856
	.globl restart_int_handler
Linus Torvalds's avatar
Linus Torvalds committed
857
restart_int_handler:
Heiko Carstens's avatar
Heiko Carstens committed
858 859 860 861 862 863 864 865
	lg	%r15,__LC_SAVE_AREA+120 # load ksp
	lghi	%r10,__LC_CREGS_SAVE_AREA
	lctlg	%c0,%c15,0(%r10) # get new ctl regs
	lghi	%r10,__LC_AREGS_SAVE_AREA
	lam	%a0,%a15,0(%r10)
	lmg	%r6,%r15,__SF_GPRS(%r15) # load registers from clone
	stosm	__SF_EMPTY(%r15),0x04	# now we can turn dat on
	jg	start_secondary
866
	.previous
Linus Torvalds's avatar
Linus Torvalds committed
867 868 869 870
#else
/*
 * If we do not run with SMP enabled, let the new CPU crash ...
 */
Heiko Carstens's avatar
Heiko Carstens committed
871
	.globl restart_int_handler
Linus Torvalds's avatar
Linus Torvalds committed
872
restart_int_handler:
Heiko Carstens's avatar
Heiko Carstens committed
873
	basr	%r1,0
Linus Torvalds's avatar
Linus Torvalds committed
874
restart_base:
Heiko Carstens's avatar
Heiko Carstens committed
875 876
	lpswe	restart_crash-restart_base(%r1)
	.align 8
Linus Torvalds's avatar
Linus Torvalds committed
877
restart_crash:
Heiko Carstens's avatar
Heiko Carstens committed
878
	.long  0x000a0000,0x00000000,0x00000000,0x00000000
Linus Torvalds's avatar
Linus Torvalds committed
879 880 881 882 883 884 885 886 887 888 889
restart_go:
#endif

#ifdef CONFIG_CHECK_STACK
/*
 * The synchronous or the asynchronous stack overflowed. We are dead.
 * No need to properly save the registers, we are going to panic anyway.
 * Setup a pt_regs so that show_trace can provide a good call trace.
 */
stack_overflow:
	lg	%r15,__LC_PANIC_STACK	# change to panic stack
890
	aghi	%r15,-SP_SIZE
Linus Torvalds's avatar
Linus Torvalds committed
891 892 893 894 895 896 897
	mvc	SP_PSW(16,%r15),0(%r12)	# move user PSW to stack
	stmg	%r0,%r11,SP_R0(%r15)	# store gprs %r0-%r11 to kernel stack
	la	%r1,__LC_SAVE_AREA
	chi	%r12,__LC_SVC_OLD_PSW
	je	0f
	chi	%r12,__LC_PGM_OLD_PSW
	je	0f
898
	la	%r1,__LC_SAVE_AREA+32
Heiko Carstens's avatar
Heiko Carstens committed
899
0:	mvc	SP_R12(32,%r15),0(%r1)	# move %r12-%r15 to stack
900
	mvc	SP_ARGS(8,%r15),__LC_LAST_BREAK
Heiko Carstens's avatar
Heiko Carstens committed
901 902
	xc	__SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15) # clear back chain
	la	%r2,SP_PTREGS(%r15)	# load pt_regs
Linus Torvalds's avatar
Linus Torvalds committed
903 904 905 906 907 908 909 910
	jg	kernel_stack_overflow
#endif

cleanup_table_system_call:
	.quad	system_call, sysc_do_svc
cleanup_table_sysc_return:
	.quad	sysc_return, sysc_leave
cleanup_table_sysc_leave:
911
	.quad	sysc_leave, sysc_done
Linus Torvalds's avatar
Linus Torvalds committed
912
cleanup_table_sysc_work_loop:
913
	.quad	sysc_work_loop, sysc_work_done
914 915
cleanup_table_io_return:
	.quad	io_return, io_leave
916 917 918
cleanup_table_io_leave:
	.quad	io_leave, io_done
cleanup_table_io_work_loop:
919
	.quad	io_work_loop, io_work_done
Linus Torvalds's avatar
Linus Torvalds committed
920 921 922 923 924 925 926 927 928 929 930 931 932 933 934 935 936 937 938 939

cleanup_critical:
	clc	8(8,%r12),BASED(cleanup_table_system_call)
	jl	0f
	clc	8(8,%r12),BASED(cleanup_table_system_call+8)
	jl	cleanup_system_call
0:
	clc	8(8,%r12),BASED(cleanup_table_sysc_return)
	jl	0f
	clc	8(8,%r12),BASED(cleanup_table_sysc_return+8)
	jl	cleanup_sysc_return
0:
	clc	8(8,%r12),BASED(cleanup_table_sysc_leave)
	jl	0f
	clc	8(8,%r12),BASED(cleanup_table_sysc_leave+8)
	jl	cleanup_sysc_leave
0:
	clc	8(8,%r12),BASED(cleanup_table_sysc_work_loop)
	jl	0f
	clc	8(8,%r12),BASED(cleanup_table_sysc_work_loop+8)
940
	jl	cleanup_sysc_return
941 942 943 944 945
0:
	clc	8(8,%r12),BASED(cleanup_table_io_return)
	jl	0f
	clc	8(8,%r12),BASED(cleanup_table_io_return+8)
	jl	cleanup_io_return
946 947 948 949 950 951 952 953 954 955
0:
	clc	8(8,%r12),BASED(cleanup_table_io_leave)
	jl	0f
	clc	8(8,%r12),BASED(cleanup_table_io_leave+8)
	jl	cleanup_io_leave
0:
	clc	8(8,%r12),BASED(cleanup_table_io_work_loop)
	jl	0f
	clc	8(8,%r12),BASED(cleanup_table_io_work_loop+8)
	jl	cleanup_io_return
Linus Torvalds's avatar
Linus Torvalds committed
956 957 958 959 960
0:
	br	%r14

cleanup_system_call:
	mvc	__LC_RETURN_PSW(16),0(%r12)
961 962 963 964 965 966
	cghi	%r12,__LC_MCK_OLD_PSW
	je	0f
	la	%r12,__LC_SAVE_AREA+32
	j	1f
0:	la	%r12,__LC_SAVE_AREA+64
1:
Linus Torvalds's avatar
Linus Torvalds committed
967 968 969 970 971 972 973 974 975
#ifdef CONFIG_VIRT_CPU_ACCOUNTING
	clc	__LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+8)
	jh	0f
	mvc	__LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
0:	clc	__LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+16)
	jhe	cleanup_vtime
#endif
	clc	__LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn)
	jh	0f
976 977 978
	mvc	__LC_SAVE_AREA(32),0(%r12)
0:	stg	%r13,8(%r12)
	stg	%r12,__LC_SAVE_AREA+96	# argh
979
	SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
980
	CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
981 982
	lg	%r12,__LC_SAVE_AREA+96	# argh
	stg	%r15,24(%r12)
Linus Torvalds's avatar
Linus Torvalds committed
983 984 985 986 987 988 989 990 991 992 993 994 995 996 997 998 999 1000 1001
	llgh	%r7,__LC_SVC_INT_CODE
#ifdef CONFIG_VIRT_CPU_ACCOUNTING
cleanup_vtime:
	clc	__LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+24)
	jhe	cleanup_stime
	UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
cleanup_stime:
	clc	__LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+32)
	jh	cleanup_update
	UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
cleanup_update:
	mvc	__LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
#endif
	mvc	__LC_RETURN_PSW+8(8),BASED(cleanup_table_system_call+8)
	la	%r12,__LC_RETURN_PSW
	br	%r14
cleanup_system_call_insn:
	.quad	sysc_saveall
#ifdef CONFIG_VIRT_CPU_ACCOUNTING
Heiko Carstens's avatar
Heiko Carstens committed
1002 1003 1004 1005
	.quad	system_call
	.quad	sysc_vtime
	.quad	sysc_stime
	.quad	sysc_update
Linus Torvalds's avatar
Linus Torvalds committed
1006 1007 1008 1009 1010 1011 1012 1013 1014 1015
#endif

cleanup_sysc_return:
	mvc	__LC_RETURN_PSW(8),0(%r12)
	mvc	__LC_RETURN_PSW+8(8),BASED(cleanup_table_sysc_return)
	la	%r12,__LC_RETURN_PSW
	br	%r14

cleanup_sysc_leave:
	clc	8(8,%r12),BASED(cleanup_sysc_leave_insn)
1016
	je	2f
Linus Torvalds's avatar
Linus Torvalds committed
1017 1018 1019
#ifdef CONFIG_VIRT_CPU_ACCOUNTING
	mvc	__LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
	clc	8(8,%r12),BASED(cleanup_sysc_leave_insn+8)
1020
	je	2f
Linus Torvalds's avatar
Linus Torvalds committed
1021 1022
#endif
	mvc	__LC_RETURN_PSW(16),SP_PSW(%r15)
1023 1024 1025 1026 1027 1028
	cghi	%r12,__LC_MCK_OLD_PSW
	jne	0f
	mvc	__LC_SAVE_AREA+64(32),SP_R12(%r15)
	j	1f
0:	mvc	__LC_SAVE_AREA